Le blog de Romain Dedenis

Pour se faire, nous allons repartir d'un précédent tutoriel ( Flash AS 3.0 : Capturer le son du microphone (lire, enregistrer ...) ), et on va y apporter quelques modifications. Donc avant toute chose, commencez par ce dernier !

Une fois que vous aurez suivit ce premier tutoriel, nous allons maintenant rajouter une bibliothèque (pensez bien à la lier à votre .fla):

• La lib Shine disponible à cette adresse : shine.swc.
• ShineMP3Encoder disponible à cette adresse : ShineMP3Encoder.zip (l'extraire dans le repertoire du projet)

Code source

Ici, nous allons juste un peu adapter notre code pour venir y intégrer le convertisseur mp3. Allez c'est partit! :) (en vert les ajouts et/ou modifications).

package{
    import org.bytearray.micrecorder.encoder.WaveEncoder;
    import org.bytearray.micrecorder.MicRecorder;
    import org.bytearray.micrecorder.events.RecordingEvent;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.display.MovieClip;
    import org.as3wavsound.WavSound;
    import flash.net.FileReference;

    import fr.kikko.lab.ShineMP3Encoder;

    public class Main extends MovieClip{
        private var volume:Number = .5;
        private var wavEncoder:WaveEncoder;
        private var recorder:MicRecorder;
        private var fileReference:FileReference;

        private var shine:ShineMP3Encoder;
       
        public function Main(){
            wavEncoder = new WaveEncoder( volume );
            recorder = new MicRecorder( wavEncoder );

            recorder.addEventListener( RecordingEvent.RECORDING, onRecording);
            recorder.addEventListener( Event.COMPLETE, onRecordComplete);

            btn.addEventListener( MouseEvent.CLICK, btnClick);

            btn.label = "Record";
            btn_save.alpha = 0;
            btn_save.addEventListener( MouseEvent.CLICK, save);

            fileReference = new FileReference();
        }
       
        private function onRecording(e:RecordingEvent){
            trace("recording");
        }
       
        private function onRecordComplete(e:Event){
            //var player:WavSound = new WavSound( recorder.output );
            //player.play();
        }
       
        private function btnClick(e:MouseEvent){
            if(btn.label == "Record"){
                btn.label = "Stop";
                recorder.record();
            } else {
                btn.label = "Record";
                recorder.stop();
                btn_save.alpha = 1;

                shine = new ShineMP3Encoder(recorder.output);

                     shine.addEventListener(Event.COMPLETE, save);

                     shine.start();

            }
        }
       
        private function save(e:Event){
            fileReference.save ( shine.mp3Data, "recording.mp3" );
        }
    }
}

Et vous voilà maintenant capable d'enregistrer le son provenant du micro en MP3!!! Enjoy :)

Ce tutoriel vous a été utile?Abonnez-vous au fil RSS !

Ce soir nous allons nous pencher sur les objets dynamiques en Flash. Plusieurs d'entre vous m'ont demandé comment il est possible en as3 de récupérer le nom des attributs d'un objet dynamique ainsi que leur valeurs.

Prenons un exemple d'objet dynamique simple :

var o:Object = new Object();

o.name= "monMovieClip";

o.x = 100;

o.y = 120;

Imaginons maintenant que nous souhaitons affecter les valeurs de cet objet à un MovieClip. Il nous serait possible de faire comme ceci :

var monMC:MovieClip = new MovieClip();

monMC.name = o.name;

monMC.x = o.x;

monMC.y = o.y;

Ok me direz vous, mais si nous ne connaissons pas tous les attributs présents dans o comment faisons nous? Et bien justement, voici une méthode pour s'en affranchir :).

var monMC:MovieClip = new MovieClip();

for( var key:String in o){

   monMC[key] = o[key];

}

Maintenant que nous avons vu les bases, mettons en situation ce code pour mieux comprendre son intérêt.

Nous allons réaliser une classe qui va charger un fichier xml qui contiendra diverses informations d'un MovieClip qui sera ensuite placer sur la scène (par flegme et parce que je sais que vous êtes capable de loader un fichier XML tout seul, je vais intégrer directement le XML dans mon code, sans le charger ^^).

package{
    import flash.display.Sprite;
    import flash.display.MovieClip;
   
    public class Main extends Sprite{
       
        public function Main(){
            var xml:XML = <App>
                            <config>
                                <name>monMovieClip</name>
                                <x>150</x>
                                <y>100</y>
                                <width>250</width>
                                <height>120</height>
                            </config>
                          </App>;
           
            var o:Object = new Object();
            //On affecte les valeurs du XML à notre objet (name, x, y...)
            for each(var attribut:XML in xml.config.children()){
                o[attribut.localName()] = attribut.text();
            }
           
            var monMC:MovieClip = new MovieClip();
            //On affecte les valeurs de notre objet au MovieClip (name, x, y...).
            for(var key:String in o){
                monMC[key] = o[key];
            }
            addChild(monMC);
        }
    }
}

Dans cet exemple, il est vrai qu'une telle solution n'est pas très utile... Mais je compte sur votre imagination fertile pour mettre en application ce code :).

Vous avez trouvé cet article intéressant? Abonnez-vous au fil RSS !

Romain Dedenis.

Le player Flash 10.1 intègre la gestion du multitouch (flash.ui.Multitouch) pour les écrans tactiles voir pour des applications mobiles (je vous présenterai dans un prochain tuto comment transformer votre application Flash en application Android pour mobile ou tablette).

Nous allons réaliser très simplement une petite application prenant en compte le multitouch en utilisant TransformGestureEvent.

I/ Présentation rapide de TransformGestureEvent.

Cette classe présente dans flash.events nous permet d'utiliser la gestion des gestures du multitouch.

Hum hum, c'est à dire?! En fait la gesture est simplement le fait d'associer une action à un mouvement des doigts bien précis. Par exemple, comme sur un Iphone ou autre smartphone, quand vous faite glisser votre doigt de haut en bas de l'écran, ceci déclenche le défilement de l'information. Et bah voilà, c'est simplement ça la gesture.

Pour nous simplifier la vie, TransformGestureEvent intègre la prise en charge des 4 "grands" type de Gesture : La rotation, le zoom, le défilement et le glisser (respectivement Rotate, Zoom, Pan et Swipe). Ces actions s'effectuent avec 2 doigts sur l'écran.

II/ Application à travers un exemple de TransformGestureEvent.

Dans cette exemple, nous allons dessiner un rectangle rouge que nous allons rendre sensible à la gesture multitouch.

code source

package{
    import flash.display.Sprite;
    import flash.ui.Multitouch;
    import flash.ui.MultitouchInputMode;
    import flash.events.TransformGestureEvent;
   
    public class GestureTest extends Sprite{
       
        public function GestureTest(){
            //On indique à Flash qu'il faut qu'il prenne en compte le Multitouch en mode gesture
            Multitouch.inputMode = MultitouchInputMode.GESTURE;
           
            //On créer un rectangle rouge
            var spr:Sprite = new Sprite();
            spr.graphics.beginFill(0xff0000);
            spr.graphics.drawRect(-50, -50, 100, 100);
            spr.graphics.endFill();
            spr.x = 200;
            spr.y = 150;
            addChild(spr);
           
            //On ajoute les évênements de gesture au rectangle (zoom, rotation, defilement)
            spr.addEventListener(TransformGestureEvent.GESTURE_ZOOM, onZoom);
            spr.addEventListener(TransformGestureEvent.GESTURE_ROTATE, onRotate);
            spr.addEventListener(TransformGestureEvent.GESTURE_PAN, onPan);
        }
       
        private function onZoom(e:TransformGestureEvent):void{
            //e.scaleX et e.scaleY permettent de récupérer l'agrandissement en largeur et en hauteur
            e.target.scaleX *= e.scaleX;
            e.target.scaleY *= e.scaleY;
        }
       
        private function onRotate(e:TransformGestureEvent):void{
            //e.rotation nous permet de récuperer l'angle de rotation correspondant à la gesture
            e.target.rotation += e.rotation;
        }

        private function onPan(e:TransformGestureEvent):void{
            //e.stageX et e.stageY nous permettent de récupérer la position de sur la scene de la gesture
            e.target.x = e.stageX;
            e.target.y = e.stageY;
        }
    }
}

Noubliez pas, nous faisons du multitouch donc c'est avec les 2 doigts que doivent s'effectuer les actions ci-dessus!

Comme je vous le disais plus haut, je vous présenterais bientôt une méthode très simple pour transformer votre application Flash en application pour Android ! En attendant, amusez vous bien avec le multitouch :)

Vous avez trouvé cet article intéressant? Abonnez-vous au fil RSS !

Romain Dedenis.