Le blog de Romain Dedenis

Avant d'aborder à proprement parler la réalité augmentée, nous allons commencer par une notion essentielle, qui est la détection de mouvements.

I/ Le principe

Le principe de la détection de mouvements basique est basé sur l'analyse des différences entre 2 images consécutives.
Des fonctions existent en flash pour nous permettre de faire directement la différence entre ces deux images, nous nous appuyerons donc dessus pour ce tutoriel.


II/ Mise en application

Pour capturer les images qui vont être analysées, nous allons utiliser notre WebCam (tutoriel sur l'utilisation de WebCam).

Comme pour les tutoriels de PaperVision, je vais commencer par vous donner le code source que vous tenterez de comprendre par vous même, puis je passerais aux explications par la suite.

package{
    import flash.display.*;
    import flash.events.*;
    import flash.geom.*;
    import flash.utils.*;
    import flash.media.Camera;
    import flash.media.Video;
       
    public class Main extends MovieClip{
        private var camera:Camera;
        private var video:Video;
       
        private var now:BitmapData;
        private var before:BitmapData;
        private var bmp:Bitmap;

        private var pt:Point;
       
        public function Main():void{
            init();
        }
       
        public function init():void{
            //initialisation de la caméra
            camera = Camera.getCamera();
            camera.setMode(640,480,15);
            camera.addEventListener(StatusEvent.STATUS, startRender);
            //initialisation de la video
            video = new Video(640,480);
            video.attachCamera(camera);
            //initialisation BitmapData
            now = new BitmapData(camera.width, camera.height);
            before = new BitmapData(camera.width, camera.height);
            bmp = new Bitmap();
            addChild(bmp);
            //initialisation des autres outils neccessaires
            pt = new Point(0, 0);
        }
       
        private function startRender(e:StatusEvent):void{
            if(e.code == "Camera.Unmuted"){
                setInterval(traceMotion, 200);
            }
        }
       
        public function traceMotion(e:Event=null):void{
            now.draw(video); // (1)
            now.draw(before, null, null, 'difference'); // (2)
            var sens = 0xff111111;
            now.threshold(now, now.rect, pt, ">", sens, 0xffffffff); // (3)
            before.draw(video); // (4)
           
            bmp.bitmapData = now; // on affiche le résultat à l'écran
        }
    }
}

A chacun de vos mouvements devant la WebCam, celui-ci sera retransmis en blanc sur l'image.