Pré-requis :
- créer un identifiant Google Map API http://code.google.com/intl/fr-FR/apis/maps/signup.html.
- télécharger l'API map de Google pour AS3 http://maps.googleapis.com/maps/flash/release/sdk.zip.
Maintenant, créez un fla et attachez lui un fichier Main.as. Ensuite, dans les paramètres avancés d'ActionScript 3.0, ajoutez un chemin de bibliothèque pointant vers le fichier map_1_20.swc précédemment téléchargé.
Et hop c'est partit!
Code source
package{
import flash.display.Sprite;
import flash.geom.Point;
import com.google.maps.Map;
import com.google.maps.MapEvent;
import com.google.maps.LatLng;
import com.google.maps.MapType;
import com.google.maps.overlays.Marker;
import com.google.maps.overlays.MarkerOptions;
import flash.text.TextField;
public class Main extends Sprite{
private var map:Map;
public function Main(){
map = new Map();
map.key = "votre clé pour l'API Google Map";
map.setSize(new Point(550, 400));
map.addEventListener(MapEvent.MAP_READY, initMapView);
addChild(map);
}
private function initMapView(e:MapEvent):void{
//Lattitude et longitude des points que l'on va afficher sur la carte
var latlng:LatLng = new LatLng(44.833, -0.567);
var latlng2:LatLng = new LatLng(46.2556, 5.655);
var lalngCenterMap:LatLng = new LatLng(45, 3);
//Les markers à ajouter sur la map
var marker:Marker = new Marker(latlng);
var marker2:Marker = new Marker(latlng2);
//Personnalisation d'un marker avec un TextField
var mo:MarkerOptions = new MarkerOptions();
var textField:TextField = new TextField();
textField.htmlText = "<b>Romain Dedenis - Bordeaux</b>";
textField.background = true;
textField.autoSize = "center";
textField.backgroundColor = 0xee0000;
mo.icon = textField;
marker.setOptions(mo);
//On définit le point sur lequel la map va se centrer, son niveau de zoom et son type
map.setCenter(lalngCenterMap, 6, MapType.NORMAL_MAP_TYPE);
//On ajoute les points sur la carte
map.addOverlay(marker);
map.addOverlay(marker2);
//On désactive le drag and drop
map.disableDragging();
//On désactive le zoom via la molette de la souris
map.disableScrollWheelZoom();
}
}
}
Voila la fin de cet article sur l'utilisation basique de l'API Google Map. A vous d'approfondir la question maintenant :).